目前已有若干版本的子程序库公开发表，它们各有特色。笔者在1988年也编制了两个
%A 子程序库（定点子程序库和浮点子程序库），并在相容性、透明性、容错性和算法优化方
%A 面作了一些工作。本程序库中的开平方算法为笔者研究的快速逼近算法，它能达到牛顿迭
%A 代法同样的精度，而速度加快二十倍左右，超过双字节定点除法的速度。经过八年来全国
%A 广大用户的实际使用，反馈了不少信息，陆续扩充了一些新的子程序，纠正了一些隐含错
%A 误，成为现在这个最新版本。
%A 本子程序库对《单片机应用程序设计技术》一书附录中的子程序库作了重大修订：
%A （１）按当前流行的以 IBM PC 为主机的开发系统对汇编语言的规定，将原子程序库
%A 的标号和位地址进行了调整，读者不必再进行修改，便可直接使用。
%A （２）对浮点运算子程序库进行了进一步的测试和优化，对十进制浮点数和二进制浮
%A 点数的相互转换子程序进行了彻底改写，提高了运算精度和可靠性。
%A （３）新增添了若干个浮点子程序（传送、比较、清零、判零等），使编写数据处理
%A 程序的工作变得更简单直观。
%A 在使用说明中开列了最主要的几项：标号、入口条件、出口信息、影响资源、堆栈
%A 需求，各项目的意义请参阅《单片机应用程序设计技术》第六章 6.3.7 节的内容。程序
%A 清单中开列了四个栏目：标号、指令、操作数、注释。为方便读者理解，注释尽力详细。
%A 子程序库的使用方法如下：
%A １．将子程序库全部内容链接在应用程序之后，统一编译即可。优点是简单方便，缺
%A 点是程序太长，大量无关子程序也包含在其中。
%A ２．仅将子程序库中的有关部分内容链接在应用程序之后，统一编译即可。有些子程
%A 序需要调用一些低级子程序，这些低级子程序也应该包含在内。优点是程序紧凑，缺点是
%A 需要对子程序库进行仔细删节。
%A
%A （一）ＭＣＳ－５１定点运算子程序库及其使用说明
%A 定点运算子程序库文件名为DQ51.ASM，为便于使用，先将有关约定说明如下：
%A １．多字节定点操作数：用[R0]或[R1]来表示存放在由R0或R1指示的连续单元中的数
%A 据。地址小的单元存放数据的高字节。例如：[R0]=123456H，若(R0)=30H，则(30H)=12H，
%A (31H)=34H，(32H)=56H。
%A ２．运算精度：单次定点运算精度为结果最低位的当量值。
%A ３．工作区：数据工作区固定在PSW、A、B、R2～R7，用户只要不在工作区中存放无
%A 关的或非消耗性的信息，程序就具有较好的透明性。
%A
%A （１） 标号： ＢＣＤＡ功能：多字节ＢＣＤ码加法
%A
%A 入口条件：字节数在R7中，被加数在[R0]中，加数在[R1]中。
%A 出口信息：和在[R0]中，最高位进位在CY中。
%A 影响资源：PSW、A、R2 堆栈需求： ２字节
%A
%A BCDA: MOV A,R7 ；取字节数至R2中
%A MOV R2,A
%A ADD A,R0 ；初始化数据指针
%A MOV R0,A
%A MOV A,R2
%A ADD A,R1
%A MOV R1,A
%A CLR C
%A BCD1: DEC R0 ；调整数据指针
%A DEC R1
%A MOV A,@R0
%A ADDC A,@R1 ；按字节相加
%A DA A ；十进制调整
%A MOV @R0,A ；和存回[R0]中
%A DJNZ R2,BCD1 ；处理完所有字节
%A RET
%A
%A （２） 标号： ＢＣＤＢ功能：多字节ＢＣＤ码减法
%A
%A 入口条件：字节数在R7中，被减数在[R0]中，减数在[R1]中。
%A 出口信息：差在[R0]中，最高位借位在CY中。
%A 影响资源：PSW、A、R2、R3 堆栈需求： ６字节
%A
%A BCDB: LCALL NEG1 ；减数[R1]十进制取补
%A LCALL BCDA ；按多字节ＢＣＤ码加法处理
%A CPL C ；将补码加法的进位标志转换成借位标志
%A MOV F0,C ；保护借位标志
%A LCALL NEG1 ；恢复减数[R1]的原始值
%A MOV C,F0 ；恢复借位标志
%A RET
%A NEG1: MOV A,R0 ；[R1]十进制取补子程序入口
%A XCH A,R1 ；交换指针
%A XCH A,R0
%A LCALL NEG ；通过[R0]实现[R1]取补
%A MOV A,R0
%A XCH A,R1 ；换回指针
%A XCH A,R0
%A RET
%A
%A
%A （３） 标号： ＮＥＧ功能：多字节ＢＣＤ码取补
%A
%A 入口条件：字节数在R7中，操作数在[R0]中。
%A 出口信息：结果仍在[R0]中。
%A 影响资源：PSW、A、R2、R3 堆栈需求： ２字节
%A
%A NEG: MOV A,R7 ；取（字节数减一）至R2中
%A DEC A
%A MOV R2,A
%A MOV A,R0 ；保护指针
%A MOV R3,A
%A NEG0: CLR C
%A MOV A,#99H
%A SUBB A,@R0 ；按字节十进制取补
%A MOV @R0,A ；存回[R0]中
%A INC R0 ；调整数据指针
%A DJNZ R2,NEG0 ；处理完（R2）字节
%A MOV A,#9AH ；最低字节单独取补
%A SUBB A,@R0
%A MOV @R0,A
%A MOV A,R3 ；恢复指针
%A MOV R0,A
%A RET
%A
%A （４） 标号： ＢＲＬＮ功能：多字节ＢＣＤ码左移十进制一位（乘十）
%A
%A 入口条件：字节数在R7中，操作数在[R0]中。
%A 出口信息：结果仍在[R0]中，移出的十进制最高位在R3中。
%A 影响资源：PSW、A、R2、R3 堆栈需求： ２字节
%A
%A BRLN: MOV A,R7 ；取字节数至R2中
%A MOV R2,A
%A ADD A,R0 ；初始化数据指针
%A MOV R0,A
%A MOV R3,#0 ；工作单元初始化
%A BRL1: DEC R0 ；调整数据指针
%A MOV A,@R0 ；取一字节
%A SWAP A ；交换十进制高低位
%A MOV @R0,A ；存回
%A MOV A,R3 ；取低字节移出的十进制高位
%A XCHD A,@R0 ；换出本字节的十进制高位
%A MOV R3,A ；保存本字节的十进制高位
%A DJNZ R2,BRL1 ；处理完所有字节
%A RET
%A
%A （５） 标号： ＭＵＬＤ功能：双字节二进制无符号数乘法
%A
%A 入口条件：被乘数在R2、R3中，乘数在R6、R7中。
%A 出口信息：乘积在R2、R3、R4、R5中。
%A 影响资源：PSW、A、B、R2～R7 堆栈需求： ２字节
%A
%A MULD: MOV A,R3 ；计算R3乘R7
%A MOV B,R7
%A MUL AB
%A MOV R4,B ；暂存部分积
%A MOV R5,A
%A MOV A,R3 ；计算R3乘R6
%A MOV B,R6
%A MUL AB
%A ADD A,R4 ；累加部分积
%A MOV R4,A
%A CLR A
%A ADDC A,B
%A MOV R3,A
%A MOV A,R2 ；计算R2乘R7
%A MOV B,R7
%A MUL AB
%A ADD A,R4 ；累加部分积
%A MOV R4,A
%A MOV A,R3
%A ADDC A,B
%A MOV R3,A
%A CLR A
%A RLC A
%A XCH A,R2 ；计算R2乘R6
%A MOV B,R6
%A MUL AB
%A ADD A,R3 ；累加部分积
%A MOV R3,A
%A MOV A,R2
%A ADDC A,B
%A MOV R2,A
%A RET
%A （６） 标号： ＭＵＬ２功能：双字节二进制无符号数平方
%A
%A 入口条件：待平方数在R2、R3中。
%A 出口信息：结果在R2、R3、R4、R5中。
%A 影响资源：PSW、A、B、R2～R5 堆栈需求： ２字节
%A
%A MUL2: MOV A,R3 ；计算R3平方
%A MOV B,A
%A MUL AB
%A MOV R4,B ；暂存部分积
%A MOV R5,A
%A MOV A,R2 ；计算R2平方
%A MOV B,A
%A MUL AB
%A XCH A,R3 ；暂存部分积，并换出R2和R3
%A XCH A,B
%A XCH A,R2
%A MUL AB ；计算2×R2×R3
%A CLR C
%A RLC A
%A XCH A,B
%A RLC A
%A JNC MU20
%A INC R2 ；累加溢出量
%A MU20: XCH A,B ；累加部分积
%A ADD A,R4
%A MOV R4,A
%A MOV A,R3
%A ADDC A,B
%A MOV R3,A
%A CLR A
%A ADDC A,R2
%A MOV R2,A
%A RET
%A
%A （７） 标号： ＤＩＶＤ功能：双字节二进制无符号数除法
%A
%A 入口条件：被除数在R2、R3、R4、R5中，除数在R6、R7中。
%A 出口信息：OV=0 时，双字节商在R2、R3中，OV=1 时溢出。
%A 影响资源：PSW、A、B、R1～R7 堆栈需求： ２字节
%A
%A DIVD: CLR C ；比较被除数和除数
%A MOV A,R3
%A SUBB A,R7
%A MOV A,R2
%A SUBB A,R6
%A JC DVD1
%A SETB OV ；溢出
%A RET
%A DVD1: MOV B,#10H ；计算双字节商
%A DVD2: CLR C ；部分商和余数同时左移一位
%A MOV A,R5
%A RLC A
%A MOV R5,A
%A MOV A,R4
%A RLC A
%A MOV R4,A
%A MOV A,R3
%A RLC A
%A MOV R3,A
%A XCH A,R2
%A RLC A
%A XCH A,R2
%A MOV F0,C ；保存溢出位
%A CLR C
%A SUBB A,R7 ；计算（R2R3－R6R7）
%A MOV R1,A
%A MOV A,R2
%A SUBB A,R6
%A ANL C,/F0 ；结果判断
%A JC DVD3
%A MOV R2,A ；够减，存放新的余数
%A MOV A,R1
%A MOV R3,A
%A INC R5 ；商的低位置一
%A DVD3: DJNZ B,DVD2 ；计算完十六位商（R4R5）
%A MOV A,R4 ；将商移到R2R3中
%A MOV R2,A
%A MOV A,R5
%A MOV R3,A
%A CLR OV ；设立成功标志
%A RET
%A
%A （８） 标号： Ｄ４５７功能：双字节二进制无符号数除以单字节二进制数
%A
%A 入口条件：被除数在R4、R5中，除数在R7中。
%A 出口信息：OV=0 时，单字节商在R3中，OV=1 时溢出。
%A 影响资源：PSW、A、R3～R7 堆栈需求： ２字节
%A
%A D457: CLR C
%A MOV A,R4
%A SUBB A,R7
%A JC DV50
%A SETB OV ；商溢出
%A RET
%A DV50: MOV R6,#8 ；求平均值（R4R5／R7－→R3）
%A DV51: MOV A,R5
%A RLC A
%A MOV R5,A
%A MOV A,R4
%A RLC A
%A MOV R4,A
%A MOV F0,C
%A CLR C
%A SUBB A,R7
%A ANL C,/F0
%A JC DV52
%A MOV R4,A
%A DV52: CPL C
%A MOV A,R3
%A RLC A
%A MOV R3,A
%A DJNZ R6,DV51
%A MOV A,R4 ；四舍五入
%A ADD A,R4
%A JC DV53
%A SUBB A,R7
%A JC DV54
%A DV53: INC R3
%A DV54: CLR OV
%A RET
%A （９） 标号： ＤＶ３１功能：三字节二进制无符号数除以单字节二进制数
%A
%A 入口条件：被除数在R3、R4、R5中，除数在R7中。
%A 出口信息：OV=0 时，双字节商在R4、R5中，OV=1 时溢出。
%A 影响资源：PSW、A、B、R2～R7 堆栈需求： ２字节
%A
%A DV31: CLR C
%A MOV A,R3
%A SUBB A,R7
%A JC DV30
%A SETB OV ；商溢出
%A RET
%A DV30: MOV R2,#10H ；求R3R4R5／R7－→R4R5
%A DM23: CLR C
%A MOV A,R5
%A RLC A
%A MOV R5,A
%A MOV A,R4
%A RLC A
%A MOV R4,A
%A MOV A,R3
%A RLC A
%A MOV R3,A
%A MOV F0,C
%A CLR C
%A SUBB A,R7
%A ANL C,/F0
%A JC DM24
%A MOV R3,A
%A INC R5
%A DM24: DJNZ R2,DM23
%A MOV A,R3 ；四舍五入
%A ADD A,R3
%A JC DM25
%A SUBB A,R7
%A JC DM26
%A DM25: INC R5
%A MOV A,R5
%A JNZ DM26
%A INC R4
%A DM26: CLR OV
%A RET ；商在R4R5中
%A
%A
%A （１０） 标号： ＭＵＬＳ功能：双字节二进制有符号数乘法（补码）
%A
%A 入口条件：被乘数在R2、R3中，乘数在R6、R7中。
%A 出口信息：乘积在R2、R3、R4、R5中。
%A 影响资源：PSW、A、B、R2～R7 堆栈需求： ４字节
%A
%A MULS: MOV R4,#0 ；清零R4R5
%A MOV R5,#0
%A LCALL MDS ；计算结果的符号和两个操作数的绝对值
%A LCALL MULD ；计算两个绝对值的乘积
%A SJMP MDSE ；用补码表示结果
%A
%A （１１） 标号： ＤＩＶＳ功能：双字节二进制有符号数除法（补码）
%A
%A 入口条件：被除数在R2、R3、R4、R5中，除数在R6、R7中。
%A 出口信息：OV=0时商在R2、R3中，OV=1时溢出。
%A 影响资源：PSW、A、B、R1～R7 堆栈需求： ５字节
%A
%A DIVS: LCALL MDS ；计算结果的符号和两个操作数的绝对值
%A PUSH PSW ；保存结果的符号
%A LCALL DIVD ；计算两个绝对值的商
%A JNB OV,DVS1 ；溢出否？
%A POP ACC ；溢出，放去结果的符号，保留溢出标志
%A RET
%A DVS1: POP PSW ；未溢出，取出结果的符号
%A MOV R4,#0
%A MOV R5,#0
%A MDSE: JB F0,MDS2 ；用补码表示结果
%A CLR OV ；结果为正，原码即补码，计算成功
%A RET
%A MDS: CLR F0 ；结果符号初始化
%A MOV A,R6 ；判断第二操作数的符号
%A JNB ACC.7,MDS1；为正，不必处理
%A CPL F0 ；为负，结果符号取反
%A XCH A,R7 ；第二操作数取补，得到其绝对值
%A CPL A
%A ADD A,#1
%A XCH A,R7
%A CPL A
%A ADDC A,#0
%A MOV R6,A
%A MDS1: MOV A,R2 ；判断第一操作数或运算结果的符号
%A JNB ACC.7,MDS3；为正，不必处理
%A CPL F0 ；为负，结果符号取反
%A MDS2: MOV A,R5 ；求第一操作数的绝对值或运算结果的补码
%A CPL A
%A ADD A,#1
%A MOV R5,A
%A MOV A,R4
%A CPL A
%A ADDC A,#0
%A MOV R4,A
%A MOV A,R3
%A CPL A
%A ADDC A,#0
%A MOV R3,A
%A MOV A,R2
%A CPL A
%A ADDC A,#0
%A MOV R2,A
%A MDS3: CLR OV ；运算成功
%A RET
%A
%A （１２） 标号： ＳＨ２功能：双字节二进制无符号数开平方（快速）
%A
%A 入口条件：被开方数在R2、R3中。
%A 出口信息：平方根仍在R2、R3中，整数部分的位数为原数的一半，其余为小数。
%A 影响资源：PSW、A、B、R2～R7 堆栈需求： ２字节
%A
%A SH2: MOV A,R2
%A ORL A,R3
%A JNZ SH20
%A RET ；被开方数为零，不必运算
%A SH20: MOV R7,#0 ；左规次数初始化
%A MOV A,R2
%A SH22: ANL A,#0C0H ；被开方数高字节小于４０Ｈ否？
%A JNZ SQRH ；不小于４０Ｈ，左规格化完成，转开方过程
%A CLR C ；每左规一次，被开方数左移两位
%A MOV A,R3
%A RLC A
%A MOV F0,C
%A CLR C
%A RLC A
%A MOV R3,A
%A MOV A,R2
%A MOV ACC.7,C
%A MOV C,F0
%A RLC A
%A RLC A
%A MOV R2,A
%A INC R7 ；左规次数加一
%A SJMP SH22 ；继续左规
%A
%A （１３） 标号： ＳＨ４功能：四字节二进制无符号数开平方（快速）
%A
%A 入口条件：被开方数在R2、R3、R4、R5中。
%A 出口信息：平方根在R2、R3中，整数部分的位数为原数的一半，其余为小数。
%A 影响资源：PSW、A、B、R2～R7 堆栈需求： ２字节
%A
%A SH4: MOV A,R2
%A ORL A,R3
%A ORL A,R4
%A ORL A,R5
%A JNZ SH40
%A RET ；被开方数为零，不必运算
%A SH40: MOV R7,#0 ；左规次数初始化
%A MOV A,R2
%A SH41: ANL A,#0C0H ；被开方数高字节小于４０Ｈ否？
%A JNZ SQRH ；不小于４０Ｈ，左规格化完成
%A MOV R6,#2 ；每左规一次，被开方数左移两位
%A SH42: CLR C ；被开方数左移一位
%A MOV A,R5
%A RLC A
%A MOV R5,A
%A MOV A,R4
%A RLC A
%A MOV R4,A
%A MOV A,R3
%A RLC A
%A MOV R3,A
%A MOV A,R2
%A RLC A
%A MOV R2,A
%A DJNZ R6,SH42 ；被开方数左移完两位
%A INC R7 ；左规次数加一
%A SJMP SH41 ；继续左规
%A SQRH: MOV A,R2 ；规格化后高字节按折线法分为三个区间
%A ADD A,#57H
%A JC SQR2
%A ADD A,#45H
%A JC SQR1
%A ADD A,#24H
%A MOV B,#0E3H ；第一区间的斜率
%A MOV R4,#80H ；第一区间的平方根基数
%A SJMP SQR3
%A SQR1: MOV B,#0B2H ；第二区间的斜率
%A MOV R4,#0A0H；第二区间的平方根基数
%A SJMP SQR3
%A SQR2: MOV B,#8DH ；第三区间的斜率
%A MOV R4,#0D0H；第三区间的平方根基数
%A SQR3: MUL AB ；与区间基点的偏移量乘区间斜率
%A MOV A,B
%A ADD A,R4 ；累加到平方根的基数上
%A MOV R4,A
%A MOV B,A
%A MUL AB ；求当前平方根的幂
%A XCH A,R3 ；求偏移量（存放在R2R3中）
%A CLR C
%A SUBB A,R3
%A MOV R3,A
%A MOV A,R2
%A SUBB A,B
%A MOV R2,A
%A SQR4: SETB C ；用减奇数法校正一个字节的平方根
%A MOV A,R4 ；当前平方根的两倍加一存入R5R6中
%A RLC A
%A MOV R6,A
%A CLR A
%A RLC A
%A MOV R5,A
%A MOV A,R3 ；偏移量小于该奇数否？
%A SUBB A,R6
%A MOV B,A
%A MOV A,R2
%A SUBB A,R5
%A JC SQR5 ；小于，校正结束，已达到一个字节的精度
%A INC R4 ；不小于，平方根加一
%A MOV R2,A ；保存新的偏移量
%A MOV R3,B
%A SJMP SQR4 ；继续校正
%A SQR5: MOV A,R4 ；将一个字节精度的根存入R2
%A XCH A,R2
%A RRC A
%A MOV F0,C ；保存最终偏移量的最高位
%A MOV A,R3
%A MOV R5,A ；将最终偏移量的低八位存入R5中
%A MOV R4,#8 ；通过（R5R6／R2）求根的低字节
%A SQR6: CLR C
%A MOV A,R3
%A RLC A
%A MOV R3,A
%A CLR C
%A MOV A,R5
%A SUBB A,R2
%A JB F0,SQR7
%A JC SQR8
%A SQR7: MOV R5,A
%A INC R3
%A SQR8: CLR C
%A MOV A,R5
%A RLC A
%A MOV R5,A
%A MOV F0,C
%A DJNZ R4,SQR6 ；根的第二字节计算完，在R3中
%A MOV A,R7 ；取原被开方数的左规次数
%A JZ SQRE ；未左规，开方结束
%A SQR9: CLR C ；按左规次数右移平方根，得到实际根
%A MOV A,R2
%A RRC A
%A MOV R2,A
%A MOV A,R3
%A RRC A
%A MOV R3,A
%A DJNZ R7,SQR9
%A SQRE: RET
%A （１４） 标号： ＨＡＳＣ功能：单字节十六进制数转换成双字节ASCII码
%A
%A 入口条件：待转换的单字节十六进制数在累加器A中。
%A 出口信息：高四位的ASCII码在A中，低四位的ASCII码在B中。
%A 影响资源：PSW、A、B 堆栈需求： ４字节
%A
%A HASC: MOV B,A ；暂存待转换的单字节十六进制数
%A LCALL HAS1 ；转换低四位
%A XCH A,B ；存放低四位的ASCII码
%A SWAP A ；准备转换高四位
%A HAS1: ANL A,#0FH ；将累加器的低四位转换成ASCII码
%A ADD A,#90H
%A DA A
%A ADDC A,#40H
%A DA A
%A RET
%A
%A （１５） 标号： ＡＳＣＨ 功能：ASCII码转换成十六进制数
%A
%A 入口条件：待转换的ASCII码（30H～39H或41H～46H）在A中。
%A 出口信息：转换后的十六进制数（00H～0FH）仍在累加器A中。
%A 影响资源：PSW、A 堆栈需求： ２字节
%A
%A ASCH: CLR C
%A SUBB A,#30H
%A JNB ACC.4,ASH1
%A SUBB A,#7
%A ASH1: RET
%A
%A （１６） 标号：ＨＢＣＤ功能：单字节十六进制整数转换成单字节ＢＣＤ码整数
%A
%A 入口条件：待转换的单字节十六进制整数在累加器A中。
%A 出口信息：转换后的ＢＣＤ码整数（十位和个位）仍在累加器A中，百位在R3中。
%A 影响资源：PSW、A、B、R3 堆栈需求： ２字节
%A
%A HBCD: MOV B,#100 ；分离出百位，存放在R3中
%A DIV AB
%A MOV R3,A
%A MOV A,#10 ；余数继续分离十位和个位
%A XCH A,B
%A DIV AB
%A SWAP A
%A ORL A,B ；将十位和个位拼装成ＢＣＤ码
%A RET
%A
%A （１７） 标号： ＨＢ２功能：双字节十六进制整数转换成双字节ＢＣＤ码整数
%A
%A 入口条件：待转换的双字节十六进制整数在R6、R7中。
%A 出口信息：转换后的三字节ＢＣＤ码整数在R3、R4、R5中。
%A 影响资源：PSW、A、R2～R7 堆栈需求： ２字节
%A
%A HB2: CLR A ；ＢＣＤ码初始化
%A MOV R3,A
%A MOV R4,A
%A MOV R5,A
%A MOV R2,#10H ；转换双字节十六进制整数
%A HB3: MOV A,R7 ；从高端移出待转换数的一位到CY中
%A RLC A
%A MOV R7,A
%A MOV A,R6
%A RLC A
%A MOV R6,A
%A MOV A,R5 ；ＢＣＤ码带进位自身相加，相当于乘２
%A ADDC A,R5
%A DA A ；十进制调整
%A MOV R5,A
%A MOV A,R4
%A ADDC A,R4
%A DA A
%A MOV R4,A
%A MOV A,R3
%A ADDC A,R3
%A MOV R3,A ；双字节十六进制数的万位数不超过６，不用调整
%A DJNZ R2,HB3 ；处理完１６ｂｉｔ
%A RET
%A
%A （１８） 标号： ＨＢＤ功能：单字节十六进制小数转换成单字节ＢＣＤ码小数
%A
%A 入口条件：待转换的单字节十六进制小数在累加器A中。
%A 出口信息：CY=0时转换后的ＢＣＤ码小数仍在A中。CY=1时原小数接近整数１。
%A 影响资源：PSW、A、B 堆栈需求： ２字节
%A
%A HBD: MOV B,#100 ；原小数扩大一百倍
%A MUL AB
%A RLC A ；余数部分四舍五入
%A CLR A
%A ADDC A,B
%A MOV B,#10 ；分离出十分位和百分位
%A DIV AB
%A SWAP A
%A ADD A,B ；拼装成单字节ＢＣＤ码小数
%A DA A ；调整后若有进位，原小数接近整数１
%A RET
%A
%A （１９） 标号： ＨＢＤ２功能：双字节十六进制小数转换成双字节ＢＣＤ码小数
%A
%A 入口条件：待转换的双字节十六进制小数在R2、R3中。
%A 出口信息：转换后的双字节ＢＣＤ码小数仍在R2、R3中。
%A 影响资源：PSW、A、B、R2、R3、R4、R5 堆栈需求：６字节
%A
%A HBD2: MOV R4,#4 ；四位十进制码
%A HBD3: MOV A,R3 ；原小数扩大十倍
%A MOV B,#10
%A MUL AB
%A MOV R3,A
%A MOV R5,B
%A MOV A,R2
%A MOV B,#10
%A MUL AB
%A ADD A,R5
%A MOV R2,A
%A CLR A
%A ADDC A,B
%A PUSH ACC ；保存溢出的一位十进制码
%A DJNZ R4,HBD3 ；计算完四位十进制码
%A POP ACC ；取出万分位
%A MOV R3,A
%A POP ACC ；取出千分位
%A SWAP A
%A ORL A,R3 ；拼装成低字节ＢＣＤ码小数
%A MOV R3,A
%A POP ACC ；取出百分位
%A MOV R2,A
%A POP ACC ；取出十分位
%A SWAP A
%A ORL A,R2 ；拼装成高字节ＢＣＤ码小数
%A MOV R2,A
%A RET
%A （２０）标号：ＢＣＤＨ功能：单字节ＢＣＤ码整数转换成单字节十六进制整数
%A
%A 入口条件：待转换的单字节ＢＣＤ码整数在累加器A中。
%A 出口信息：转换后的单字节十六进制整数仍在累加器A中。
%A 影响资源：PSW、A、B、R4 堆栈需求： ２字节
%A
%A BCDH: MOV B,#10H ；分离十位和个位
%A DIV AB
%A MOV R4,B ；暂存个位
%A MOV B,#10 ；将十位转换成十六进制
%A MUL AB
%A ADD A,R4 ；按十六进制加上个位
%A RET
%A
%A （２１）标号： ＢＨ２功能：双字节ＢＣＤ码整数转换成双字节十六进制整数
%A
%A 入口条件：待转换的双字节ＢＣＤ码整数在R2、R3中。
%A 出口信息：转换后的双字节十六进制整数仍在R2、R3中。
%A 影响资源：PSW、A、B、R2、R3、R4 堆栈需求：４字节
%A
%A BH2: MOV A,R3 ；将低字节转换成十六进制
%A LCALL BCDH
%A MOV R3,A
%A MOV A,R2 ；将高字节转换成十六进制
%A LCALL BCDH
%A MOV B,#100 ；扩大一百倍
%A MUL AB
%A ADD A,R3 ；和低字节按十六进制相加
%A MOV R3,A
%A CLR A
%A ADDC A,B
%A MOV R2,A
%A RET
%A
%A （２２）标号： ＢＨＤ功能：单字节ＢＣＤ码小数转换成单字节十六进制小数
%A
%A 入口条件：待转换的单字节ＢＣＤ码数在累加器A中。
%A 出口信息：转换后的单字节十六进制小数仍在累加器A中。
%A 影响资源：PSW、A、R2、R3 堆栈需求： ２字节
%A
%A BHD: MOV R2,#8 ；准备计算一个字节小数
%A BHD0: ADD A,ACC ；按十进制倍增
%A DA A
%A XCH A,R3
%A RLC A ；将进位标志移入结果中
%A XCH A,R3
%A DJNZ R2,BHD0 ；共计算８ｂｉｔ小数
%A ADD A,#0B0H ；剩余部分达到０．５０否？
%A JNC BHD1 ；四舍
%A INC R3 ；五入
%A BHD1: MOV A,R3 ；取结果
%A RET
%A
%A （２３）标号： ＢＨＤ２功能：双字节ＢＣＤ码小数转换成双字节十六进制小数
%A
%A 入口条件：待转换的双字节ＢＣＤ码小数在R4、R5中。
%A 出口信息：转换后的双字节十六进制小数在R2、R3中。*
%A 影响资源：PSW、A、R2～R6 堆栈需求： ２字节
%A
%A BHD2: MOV R6,#10H ；准备计算两个字节小数
%A BHD3: MOV A,R5 ；按十进制倍增
%A ADD A,R5
%A DA A
%A MOV R5,A
%A MOV A,R4
%A ADDC A,R4
%A DA A
%A MOV R4,A
%A MOV A,R3 ；将进位标志移入结果中
%A RLC A
%A MOV R3,A
%A MOV A,R2
%A RLC A
%A MOV R2,A
%A DJNZ R6,BHD3 ；共计算１６ｂｉｔ小数
%A MOV A,R4
%A ADD A,#0B0H ；剩余部分达到０．５０否？
%A JNC BHD4 ；四舍
%A INC R3 ；五入
%A MOV A,R3
%A JNZ BHD4
%A INC R2
%A BHD4: RET
%A （２４） 标号： ＭＭ功能：求单字节十六进制无符号数据块的极值
%A
%A 入口条件：数据块的首址在DPTR中，数据个数在R7中。
%A 出口信息：最大值在R6中，地址在R2R3中；最小值在R7中，地址在R4R5中。
%A 影响资源：PSW、A、B、R1～R7 堆栈需求： ４字节
%A
%A MM: MOV B,R7 ；保存数据个数
%A MOVX A,@DPTR ；读取第一个数据
%A MOV R6,A ；作为最大值的初始值
%A MOV R7,A ；也作为最小值的初始值
%A MOV A,DPL ；取第一个数据的地址
%A MOV R3,A ；作为最大值存放地址的初始值
%A MOV R5,A ；也作为最小值存放地址的初始值
%A MOV A,DPH
%A MOV R2,A
%A MOV R4,A
%A MOV A,B ；取数据个数
%A DEC A ；减一，得到需要比较的次数
%A JZ MME ；只有一个数据，不需要比较
%A MOV R1,A ；保存比较次数
%A PUSH DPL ；保护数据块的首址
%A PUSH DPH
%A MM1: INC DPTR ；指向一个新的数据
%A MOVX A,@DPTR ；读取这个数据
%A MOV B,A ；保存
%A SETB C ；与最大值比较
%A SUBB A,R6
%A JC MM2 ；不超过当前最大值，保持当前最大值
%A MOV R6,B ；超过当前最大值，更新最大值存放地址
%A MOV R2,DPH ；同时更新最大值存放地址
%A MOV R3,DPL
%A SJMP MM3
%A MM2: MOV A,B ；与最小值比较
%A CLR C
%A SUBB A,R7
%A JNC MM3 ；大于或等于当前最小值，保持当前最小值
%A MOV R7,B ；更新最小值
%A MOV R4,DPH ；更新最小值存放地址
%A MOV R5,DPL
%A MM3: DJNZ R1,MM1 ；处理完全部数据
%A POP DPH ；恢复数据首址
%A POP DPL
%A MME: RET
%A
%A （２５） 标号： ＭＭＳ功能：求单字节十六进制有符号数据块的极值
%A
%A 入口条件：数据块的首址在DPTR中，数据个数在R7中。
%A 出口信息：最大值在R6中， 地址在R2R3中；最小值在R7中，地址在R4R5中。
%A 影响资源：PSW、A、B、R1～R7 堆栈需求： ４字节
%A
%A MMS: MOV B,R7 ；保存数据个数
%A MOVX A,@DPTR ；读取第一个数据
%A MOV R6,A ；作为最大值的初始值
%A MOV R7,A ；也作为最小值的初始值
%A MOV A,DPL ；取第一个数据的地址
%A MOV R3,A ；作为最大值存放地址的初始值
%A MOV R5,A ；也作为最小值存放地址的初始值
%A MOV A,DPH
%A MOV R2,A
%A MOV R4,A
%A MOV A,B ；取数据个数
%A DEC A ；减一，得到需要比较的次数
%A JZ MMSE ；只有一个数据，不需要比较
%A MOV R1,A ；保存比较次数
%A PUSH DPL ；保护数据块的首址
%A PUSH DPH
%A MMS1: INC DPTR ；调整数据指针
%A MOVX A,@DPTR ；读取一个数据
%A MOV B,A ；保存
%A SETB C ；与最大值比较
%A SUBB A,R6
%A JZ MMS4 ；相同，不更新最大值
%A JNB OV,MMS2 ；差未溢出，符号位有效
%A CPL ACC.7 ；差溢出，符号位取反
%A MMS2: JB ACC.7,MMS4；差为负，不更新最大值
%A MOV R6,B ；更新最大值
%A MOV R2,DPH ；更新最大值存放地址
%A MOV R3,DPL
%A SJMP MMS7
%A MMS4: MOV A,B ；与最小值比较
%A CLR C
%A SUBB A,R7
%A JNB OV,MMS6 ；差未溢出，符号位有效
%A CPL ACC.7 ；差溢出，符号位取反
%A MMS6: JNB ACC.7,MMS7；差为正，不更新最小值
%A MOV R7,B ；更新最小值
%A MOV R4,DPH ；更新最小值存放地址
%A MOV R5,DPL
%A MMS7: DJNZ R1,MMS1 ；处理完全部数据
%A POP DPH ；恢复数据首址
%A POP DPL
%A MMSE: RET
%A （２６） 标号： ＦＤＳ１功能：顺序查找（ＲＯＭ）单字节表格
%A
%A 入口条件：待查找的内容在A中，表格首址在DPTR中，表格的字节数在R7中。
%A 出口信息：OV=0时，顺序号在累加器A中；OV=1时，未找到。
%A 影响资源：PSW、A、B、R2、R6 堆栈需求： ２字节
%A
%A FDS1: MOV B,A ；保存待查找的内容
%A MOV R2,#0 ；顺序号初始化（指向表首）
%A MOV A,R7 ；保存表格的长度
%A MOV R6,A
%A FD11: MOV A,R2 ；按顺序号读取表格内容
%A MOVC A,@A+DPTR
%A CJNE A,B,FD12；与待查找的内容比较
%A CLR OV ；相同，查找成功
%A MOV A,R2 ；取对应的顺序号
%A RET
%A FD12: INC R2 ；指向表格中的下一个内容
%A DJNZ R6,FD11 ；查完全部表格内容
%A SETB OV ；未查找到，失败
%A RET
%A
%A （２７） 标号： ＦＤＳ２功能：顺序查找（ＲＯＭ）双字节表格
%A
%A 入口条件：查找内容在R4、R5中，表格首址在DPTR中，数据总个数在R7中。
%A 出口信息：OV=0时顺序号在累加器A中，地址在DPTR中；OV=1时未找到。
%A 影响资源：PSW、A、R2、R6、DPTR 堆栈需求： ２字节
%A
%A FDS2: MOV A,R7 ；保存表格中数据的个数
%A MOV R6,A
%A MOV R2,#0 ；顺序号初始化（指向表首）
%A FD21: CLR A ；读取表格内容的高字节
%A MOVC A,@A+DPTR
%A XRL A,R4 ；与待查找内容的高字节比较
%A JNZ FD22
%A MOV A,#1 ；读取表格内容的低字节
%A MOVC A,@A+DPTR
%A XRL A,R5 ；与待查找内容的低字节比较
%A JNZ FD22
%A CLR OV ；相同，查找成功
%A MOV A,R2 ；取对应的顺序号
%A RET
%A FD22: INC DPTR ；指向下一个数据
%A INC DPTR
%A INC R2 ；顺序号加一
%A DJNZ R6,FD21 ；查完全部数据
%A SETB OV ；未查找到，失败
%A RET
%A
%A （２８） 标号：ＦＤＤ１功能：对分查找（ＲＯＭ）单字节无符号增序数据表格
%A
%A 入口条件：待查找的内容在累加器A中，表格首址在DPTR中，字节数在R7中。
%A 出口信息：OV=0 时，顺序号在累加器A中；OV=1 时，未找到。
%A 影响资源：PSW、A、B、R2、R3、R4 堆栈需求：２字节
%A
%A FDD1: MOV B,A ；保存待查找的内容
%A MOV R2,#0 ；区间低端指针初始化（指向第一个数据）
%A MOV A,R7
%A DEC A
%A MOV R3,A ；区间高端指针初始化（指向最后一个数据）
%A FD61: CLR C ；判断区间大小
%A MOV A,R3
%A SUBB A,R2
%A JC FD69 ；区间消失，查找失败
%A RRC A ；取区间大小的一半
%A ADD A,R2 ；加上区间的低端
%A MOV R4,A ；得到区间的中心
%A MOVC A,@A+DPTR；读取该点的内容
%A CJNE A,B,FD65；与待查找的内容比较
%A CLR OV ；相同，查找成功
%A MOV A,R4 ；取顺序号
%A RET
%A FD65: JC FD68 ；该点的内容比待查找的内容大否？
%A MOV A,R4 ；偏大，取该点位置
%A DEC A ；减一
%A MOV R3,A ；作为新的区间高端
%A SJMP FD61 ；继续查找
%A FD68: MOV A,R4 ；偏小，取该点位置
%A INC A ；加一
%A MOV R2,A ；作为新的区间低端
%A SJMP FD61 ；继续查找
%A FD69: SETB OV ；查找失败
%A RET
%A （２９） 标号：ＦＤＤ２功能：对分查找（ＲＯＭ）双字节无符号增序数据表格
%A
%A 入口条件：查找内容在R4、R5中，表格首址在DPTR中，数据个数在R7中。
%A 出口信息：OV=0 时顺序号在累加器A中，址在DPTR中；OV=1 时未找到。
%A 影响资源：PSW、A、B、R1～R7、DPTR 堆栈需求：２字节
%A
%A FDD2: MOV R2,#0 ；区间低端指针初始化（指向第一个数据）
%A MOV A,R7
%A DEC A
%A MOV R3,A ；区间高端指针初始化，指向最后一个数据
%A MOV R6,DPH ；保存表格首址
%A MOV R7,DPL
%A FD81: CLR C ；判断区间大小
%A MOV A,R3
%A SUBB A,R2
%A JC FD89 ；区间消失，查找失败
%A RRC A ；取区间大小的一半
%A ADD A,R2 ；加上区间的低端
%A MOV R1,A ；得到区间的中心
%A MOV DPH,R6
%A CLR C ；计算区间中心的地址
%A RLC A
%A JNC FD82
%A INC DPH
%A FD82: ADD A,R7
%A MOV DPL,A
%A JNC FD83
%A INC DPH
%A FD83: CLR A ；读取该点的内容的高字节
%A MOVC A,@A+DPTR
%A MOV B,R4 ；与待查找内容的高字节比较
%A CJNE A,B,FD84；不相同
%A MOV A,#1 ；读取该点的内容的低字节
%A MOVC A,@A+DPTR
%A MOV B,R5
%A CJNE A,B,FD84；与待查找内容的低字节比较
%A MOV A,R1 ；取顺序号
%A CLR OV ；查找成功
%A RET
%A FD84: JC FD86 ；该点的内容比待查找的内容大否？
%A MOV A,R1 ；偏大，取该点位置
%A DEC A ；减一
%A MOV R3,A ；作为新的区间高端
%A SJMP FD81 ；继续查找
%A FD86: MOV A,R1 ；偏小，取该点位置
%A INC A ；加一
%A MOV R2,A ；作为新的区间低端
%A SJMP FD81 ；继续查找
%A FD89: MOV DPH,R6 ；相同，恢复首址
%A MOV DPL,R7
%A SETB OV ；查找失败
%A RET
%A
%A
%A （３０） 标号： ＤＤＭ１功能：求单字节十六进制无符号数据块的平均值
%A
%A 入口条件：数据块的首址在DPTR中，数据个数在R7中。
%A 出口信息：平均值在累加器A中。
%A 影响资源：PSW、A、R2～R6 堆栈需求： ４字节
%A
%A DDM1: MOV A,R7 ；保存数据个数
%A MOV R2,A
%A PUSH DPH
%A PUSH DPL
%A CLR A ；初始化累加和
%A MOV R4,A
%A MOV R5,A
%A DM11: MOVX A,@DPTR ；读取一个数据
%A ADD A,R5 ；累加到累加和中
%A MOV R5,A
%A JNC DM12
%A INC R4
%A DM12: INC DPTR ；调整指针
%A DJNZ R2,DM11 ；累加完全部数据
%A LCALL D457 ；求平均值（R4R5／R7－→R3）
%A MOV A,R3 ；取平均值
%A POP DPL
%A POP DPH
%A RET
%A
%A （３１） 标号： ＤＤＭ２功能：求双字节十六进制无符号数据块的平均值
%A
%A 入口条件：数据块的首址在DPTR中，双字节数据总个数在R7中。
%A 出口信息：平均值在R4、R5中。
%A 影响资源：PSW、A、R2～R6 堆栈需求： ４字节
%A
%A DDM2: MOV A,R7 ；保存数据个数
%A MOV R2,A ；初始化数据指针
%A PUSH DPL ；保持首址
%A PUSH DPH
%A CLR A ；初始化累加和
%A MOV R3,A
%A MOV R4,A
%A MOV R5,A
%A DM20: MOVX A,@DPTR ；读取一个数据的高字节
%A MOV B,A
%A INC DPTR
%A MOVX A,@DPTR ；读取一个数据的低字节
%A INC DPTR
%A ADD A,R5 ；累加到累加和中
%A MOV R5,A
%A MOV A,B
%A ADDC A,R4
%A MOV R4,A
%A JNC DM21
%A INC R3
%A DM21: DJNZ R2,DM20 ；累加完全部数据
%A POP DPH ；恢复首址
%A POP DPL
%A LJMP DV31 ；求R3R4R5／R7－→R4R5，得到平均值
%A
%A （３２） 标号： ＸＲ１功能：求单字节数据块的（异或）校验和
%A
%A 入口条件：数据块的首址在DPTR中，数据的个数在R6、R7中。
%A 出口信息：校验和在累加器A中。
%A 影响资源：PSW、A、B、R4～R7 堆栈需求： ２字节
%A
%A XR1: MOV R4,DPH ；保存数据块的首址
%A MOV R5,DPL
%A MOV A,R7 ；双字节计数器调整
%A JZ XR10
%A INC R6
%A XR10: MOV B,#0 ；校验和初始化
%A XR11: MOVX A,@DPTR ；读取一个数据
%A XRL B,A ；异或运算
%A INC DPTR ；指向下一个数据
%A DJNZ R7,XR11 ；双字节计数器减一
%A DJNZ R6,XR11
%A MOV DPH,R4 ；恢复数据首址
%A MOV DPL,R5
%A MOV A,B ；取校验和
%A RET
%A
%A （３３） 标号： ＸＲ２功能：求双字节数据块的（异或）校验和
%A
%A 入口条件：数据块的首址在DPTR中，双字节数据总个数在R6、R7中。
%A 出口信息：校验和在R2、R3中。
%A 影响资源：PSW、A、R2～R7 堆栈需求： ２字节
%A
%A XR2: MOV R4,DPH ；保存数据块的首址
%A MOV R5,DPL
%A MOV A,R7 ；双字节计数器调整
%A JZ XR20
%A INC R6
%A XR20: CLR A ；校验和初始化
%A MOV R2,A
%A MOV R3,A
%A XR21: MOVX A,@DPTR ；读取一个数据的高字节
%A XRL A,R2 ；异或运算
%A MOV R2,A
%A INC DPTR
%A MOVX A,@DPTR ；读取一个数据的低字节
%A XRL A,R3 ；异或运算
%A MOV R3,A
%A INC DPTR ；指向下一个数据
%A DJNZ R7,XR21 ；双字节计数器减一
%A DJNZ R6,XR21
%A MOV DPH,R4 ；恢复数据首址
%A MOV DPL,R5
%A RET
%A
%A （３４） 标号： ＳＯＲＴ功能：单字节无符号数据块排序（增序）
%A
%A 入口条件：数据块的首址在R0中，字节数在R7中。
%A 出口信息：完成排序（增序）
%A 影响资源：PSW、A、R2～R6 堆栈需求： ２字节
%A
%A SORT: MOV A,R7
%A MOV R5,A ；比较次数初始化
%A SRT1: CLR F0 ；交换标志初始化
%A MOV A,R5 ；取上遍比较次数
%A DEC A ；本遍比上遍减少一次
%A MOV R5,A ；保存本遍次数
%A MOV R2,A ；复制到计数器中
%A JZ SRT5 ；若为零，排序结束
%A MOV A,R0 ；保存数据指针
%A MOV R6,A
%A SRT2: MOV A,@R0 ；读取一个数据
%A MOV R3,A
%A INC R0 ；指向下一个数据
%A MOV A,@R0 ；再读取一个数据
%A MOV R4,A
%A CLR C
%A SUBB A,R3 ；比较两个数据的大小
%A JNC SRT4 ；顺序正确（增序或相同），不必交换
%A SETB F0 ；设立交换标志
%A MOV A,R3 ；将两个数据交换位置
%A MOV @R0,A
%A DEC R0
%A MOV A,R4
%A MOV @R0,A
%A INC R0 ；指向下一个数据
%A SRT4: DJNZ R2,SRT2 ；完成本遍的比较次数
%A MOV A,R6 ；恢复数据首址
%A MOV R0,A
%A JB F0,SRT1 ；本遍若进行过交换，则需继续排序
%A SRT5: RET ；排序结束
%A END
%A
%A
%A
%A